Onsdagsfondens bästa trendindikator

En trendindikator mäter förstås trenden: går kurserna upp, ned eller sidledes. Det är i princip de tre olika trendlägen vi kan ha. En svårighet med att mäta trenden är att avgöra vilket tidsperspektiv man har. Många pratar om primär (månader till år), sekundär (veckor till månader) och tertiär trend (dagar till veckor).

Bild från Vinnarbyrån: http://www.vinnarbyran.se/trender.html

För en så kallad daytrader blir det förstås timmar, minuter och sekunder istället. Genom att använda glidande medelvärden kan man bedöma trenden i olika periodlängder. Ett glidande medelvärde på 200 dagar används ofta för den primära trenden, 50 dagar för den sekundära och 10 dagar för den tertiära.

Onsdagsfondens bästa – låt vara också den enda – trendindikator baseras på glidande medelvärden, faktiskt ett helt knippe av dem. De delas in i två grupper:

• ”Investerare”. Sex glidande medelvärden med längre perioder (25, 30, 35, 40, 45, 50) som ger en bild av hur de mer långsiktiga aktörerna rör sig in och ut i en aktie eller en börs.
•  ”Traders”. Sex glidande medelvärden med kortare perioder (3, 5, 8, 10, 12, 15) som ger en bild av hur de mer kortsiktiga aktörerna rör sig in och ut i en aktie eller en börs.

Tanken är att studera hur dessa två grupper av medelvärden rör sig i förhållande till varandra och därmed kunna avgöra trenden, utan att ”luras” av hur ett enskilt medelvärde rör sig. Metoden jag inspirerats av är uppfunnen av Daryl Guppy och det går att läsa om Guppy Multiple Moving Averages (GMMA) till exempel här.

Notera att jag har lite andra periodlängder än Guppy för Investerare, som jag kände var mer logiska. Det viktiga är inte exakt vilka periodlängder man använder, utan att man har en logik mellan Investerare och Traders.

Jag (och Guppy) använder exponentiella glidande medelvärden för att jag gillar hur de tar hänsyn till all historik, men lägger mest vikt vid de senaste priserna. Enkla eller viktade medelvärden går säkerligen lika bra att använda. Perioderna kan vara minuter, timmar, dagar eller veckor. Månader eller år tror jag inte är särskilt användbara om man inte har extremt långsiktig placeringshorisont….  Se upp så att du inte testar dig fram till en kombination av glidande medelvärden och periodlängder som kanske varit lyckosam historiskt men som förmodligen kommer att fungera dåligt i framtiden.

För Onsdagsfonden har jag följande regler för att avgöra trenden baserat på de 2*6 medelvärdena:

• Om de längre investerarmedelvärdena pekar uppåt och samtliga tradermedelvärden ligger över investerarna är trenden positiv.
• Om de längre investerarmedelvärdena pekar nedåt och samtliga tradermedelvärden ligger under investerarna är trenden negativ.
• Om inget av ovanstående gäller är trenden neutral, det vill säga obestämd.

I ProRealTime är trendindikatorn +1 vid positiv trend, -1 vid negativ trend och 0 vid neutral trend. Jag använder uteslutande veckodata för att få en bättre bild av de stora rörelserna och undvika att påverkas av det dagliga bruset.

Som alltid gäller att en indikator som man baserar sina köp- och säljbeslut på inte är värd särskilt mycket i sig. Det viktiga är din kompletta placeringsstrategi som ska styra hur mycket du satsar och riskerar, och framför allt hur du hanterar utfallet av dina placeringar, oavsett om indikatorn visat ”rätt” eller slagit fel. Min egen erfarenhet säger att nyttan av trendindikatorer blir klart högre i mer långsiktiga perspektiv, som veckodiagram, samtidigt som man använder den för endast entry, det vill säga att göra en placering. Exiten, att avyttra en placering, görs bäst med en frikopplad exitmetod, då trendomslag kan vara väldigt hastiga och dramatiska, särskilt vid omslag till nedgång. Trendindikatorer kan då ta lite för lång tid på sig att indikera den nya trenden och man behöver bättre skydda sitt kapital.

Om du vill programmera en trendindikator hoppas jag följande kod jag skrivit i ProRealTime’s ProBuilder är till nytta.

//Assign EMA variables
EMA3=ExponentialAverage[3](close)
EMA5=ExponentialAverage[5](close)
EMA8=ExponentialAverage[8](close)
EMA10=ExponentialAverage[10](close)
EMA12=ExponentialAverage[12](close)
EMA15=ExponentialAverage[15](close)
EMA25=ExponentialAverage[25](close)
EMA30=ExponentialAverage[30](close)
EMA35=ExponentialAverage[35](close)
EMA40=ExponentialAverage[40](close)
EMA45=ExponentialAverage[45](close)
EMA50=ExponentialAverage[50](close)

//Check if GMMA Investors are positive or negative

ConditionGMMAInvestorsUp = EMA25 > EMA25[1] and EMA30 > EMA30[1] and EMA35 >EMA35[1] and EMA40>EMA40[1] and EMA45>EMA45[1] and EMA50>EMA50[1]

ConditionGMMAInvestorsDown = EMA25 < EMA25[1] and EMA30 < EMA30[1] and EMA35 <EMA35[1] and EMA40<EMA40[1] and EMA45<EMA45[1] and EMA50<EMA50[1]

//Calculate the lowest investor MA value
Temp1=MIN(EMA25,EMA30)
Temp2=MIN(EMA35,EMA40)
Temp3=MIN(EMA45,EMA50)
Temp4=MIN(Temp1,Temp2)
LowestInvestorMA=MIN(Temp4,Temp3)

//Calculate the highest investor MA value
Temp1=MAX(EMA25,EMA30)
Temp2=MAX(EMA35,EMA40)
Temp3=MAX(EMA45,EMA50)
Temp4=Max(Temp1,Temp2)
HighestInvestorMA=Max(Temp4,Temp3)

//Calculate the lowest trader MA value
Temp1=MIN(EMA3,EMA5)
Temp2=MIN(EMA8,EMA10)
Temp3=MIN(EMA12,EMA15)
Temp4=MIN(Temp1,Temp2)
LowestTraderMA=MIN(Temp4,Temp3)

//Calculate the highest trader MA value
Temp1=MAX(EMA3,EMA5)
Temp2=MAX(EMA8,EMA10)
Temp3=MAX(EMA12,EMA15)
Temp4=Max(Temp1,Temp2)
HighestTraderMA=Max(Temp4,Temp3)

//Are GMMA Trader MA values above GMMA Investors
ConditionGMMATradersAboveGMMAInvestors=LowestTraderMA>HighestInvestorMA

//Are GMMA Trader MA values below GMMA Investors
ConditionGMMATradersBelowGMMAInvestors=HighestTraderMA<LowestInvestorMA

//If less than 50 bars, do not show
IF BarIndex < 50 THEN
GMMATrend = Undefined
ELSE
//if GMMA Investor MAs are up and GMMA Trader MAs all above GMMA Investor, we have up trend
IF ConditionGMMAInvestorsUp and ConditionGMMATradersAboveGMMAInvestors then
GMMATrend=1
//if GMMA Investor MAs are down and GMMA Trader MAs all below GMMA Investor, we have down trend
ELSIF ConditionGMMAInvestorsDown and ConditionGMMATradersBelowGMMAInvestors then
GMMATrend=-1
//If not up nor down trend, trend is neutral
else
GMMATrend=0
endif
Endif
//Show the indicator in diagram window
Return GMMATrend